Ticket #653: stringz.d

/*******************************************************************************
        tango.stdc.stringz lacks some useful functions
        copyright:      Copyright (c) 2007 yidabu.com All rights reserved

        license:        BSD style: $(LICENSE)

        version:        Initial release: 2007

        author:         yidabu.com

*******************************************************************************/
 
module dwin.stdc.stringz;

public import tango.stdc.stringz;
private import tango.text.convert.Utf;
private import tango.core.Exception;
private import tango.sys.Common;
    

////////////////////////////////////////////////////////////////////////////////
// UTF to MBSz string
////////////////////////////////////////////////////////////////////////////////

/******************************************
 * Converts the UTF-8, UTF-16, UTF-32 string s into a null-terminated string in a Windows
 * 8-bit character set.
 *
 * Params:
 * s = UTF-8 or UTF-16 or UTF-32 string to convert.
 * codePage = is the number of the target codepage, or
 *   0 - ANSI,
 *   1 - OEM,
 *   2 - Mac
 *
 * Authors:
 *  yidabu
 */


char* toMbsz(char[] s, uint page = 0)
{
    return ( toMbsz(toUtf16z(s), page) );
}
//

/// doitto
char* toMbsz(wchar[] ws, uint page = 0)
{
    return toMbsz( tango.stdc.stringz.toUtf16z(ws), page );
}
//

/// doitto
char* toMbsz(dchar[] s, uint page = 0)
{
    return ( toMbsz(toUtf16z(s), page) );
}
//


/******************************************
 * Converts the UTF-16 null-terminated string in a Windows
 * 8-bit character set.
 *
 * Params:
 * wsz = UTF-16 null-terminated string.
 * codePage = is the number of the target codepage, or
 *   0 - ANSI,
 *   1 - OEM,
 *   2 - Mac
 *
 * Authors:
 *  yidabu
 */
// modified from std.c.windows.charset : toMBSz
char* toMbsz(wchar* wsz, uint page = 0)
{
    char[] result;
    int readLen;
    if(wsz)
    {
        result.length = WideCharToMultiByte(page, 0, wsz, -1, null, 0, null, null);

        if (result.length)
            readLen = WideCharToMultiByte(page, 0, wsz, -1, result.ptr, result.length, null, null);

        if (!readLen || readLen != result.length)
            throw new IllegalArgumentException ("Stringz.toMbsz :: " ~ SysError.lastMsg);          
    }
    return result.ptr;
}
//


////////////////////////////////////////////////////////////////////////////////
// UTF to UTF16z
////////////////////////////////////////////////////////////////////////////////

/*********************************
 * Convert array of UTF-8 or UTF-32 chars s[] to a C-style 0 terminated string.
 * tango.stdc.stringz lack this function
 */
wchar* toUtf16z(char[] s)
{
    return tango.stdc.stringz.toUtf16z( tango.text.convert.Utf.toUtf16(s) );
}
//

/// doitto
wchar* toUtf16z(dchar[] s)
{
    return tango.stdc.stringz.toUtf16z( tango.text.convert.Utf.toUtf16(s) );
}
//
    

////////////////////////////////////////////////////////////////////////////////
// MBSz to UTF 
////////////////////////////////////////////////////////////////////////////////

/**********************************************
 * Converts the null-terminated string s from a Windows 8-bit character set
 * into a UTF-8 or UTF-16 or UTF-32 char array.
 *
 * Params:
 * s = UTF-8 or UTF-16 or UTF-32 string to convert.
 * codePage = is the number of the source codepage, or
 *   0 - ANSI,
 *   1 - OEM,
 *   2 - Mac
 * Authors: yidabu
 */
char[] toUtf8(char* s, int page = 0)
{
    return tango.text.convert.Utf.toUtf8( toUtf16(s, page) );
}
//

/// doitto
wchar[] toUtf16(char* s, int page = 0)
{
    char* c;

    for (c = s; *c != 0; c++)
    {
        if (*c >= 0x80)
        {
            wchar[] result;
            int readLen;

            result.length = MultiByteToWideChar(page, 0, s, -1, null, 0);

            if (result.length)
                readLen = MultiByteToWideChar(page, 0, s, -1, result.ptr, result.length);

            if (!readLen || readLen != result.length)
                throw new IllegalArgumentException ("Stringz.toUtf16 :: "~SysError.lastMsg);                

            return result[0 .. result.length-1]; // omit trailing null
        }
    }
    return tango.text.convert.Utf.toUtf16( s[0 .. c-s] );       // string is ASCII, no conversion necessary
}
//

/// doitto
dchar[] toUtf32(char* s, int page = 0)
{
    return tango.text.convert.Utf.toUtf32( toUtf16(s, page) );
}
//