Ticket #353: RawCoutFilter.2.d

// a capturing filter on Stdout and Stderr to disable Unicode translation on
// console output
// Win32 code ripped off of Tango's (0.98 RC2) Console.Conduit, changed to
// use WriteConsoleA
// Posix code from DeviceConduit

class RawCoutFilter(bool stderr) : OutputFilter {
private:
    void error() {
        throw new IOException("RawCoutFilter error: "~SysError.lastMsg);
    }

    typeof(Stdout.stream()) superArgs() {
        return stderr ? Stderr.stream : Stdout.stream;
    }

    version (Win32) {
        HANDLE handle;
        bool redirected;

        public this() {
            reopen();

            super(superArgs());
        }

        void reopen() {
            // stderr is -12, stdout is -11
            handle = GetStdHandle(-cast(DWORD)stderr - 11);

            if (handle is null) {
                handle = CreateFileA(
                    "CONOUT$",
                    GENERIC_READ | GENERIC_WRITE,
                    FILE_SHARE_READ | FILE_SHARE_WRITE,
                    null,
                    OPEN_EXISTING,
                    0,
                    cast(HANDLE)0
                );

                if (handle is null)
                    error();
            }

            DWORD dummy;
            redirected = !GetConsoleMode(handle, &dummy);
        }

        public override size_t write(void[] src) {
            if (redirected) {
                DWORD written;

                if (!WriteFile(handle, src.ptr, src.length, &written, null))
                    error();

                return written;
            } else {
                DWORD i = src.length;

                if (i == 0)
                    return 0;

                for (auto p = src.ptr, end = src.ptr + i; p < end; p += i) {
                    if (
                        !WriteConsoleA(
                            handle,
                            p,
                            min(end - p, 32 * 1024),
                            &i,
                            null
                        )
                    )
                        error();
                }

                return src.length;
            }
        }
    } else { // Posix

        // stdout is 1, stderr is 2
        const int handle = cast(int)stderr + 1;

        public this() {
            super(superArgs());
        }

        public override size_t write(void[] src) {
            ptrdiff_t written = posix.write(handle, src.ptr, src.length);
            if (written < 0)
                error();
            return written;
        }
    }
}