root/trunk/tango/scrapple/util/uuid/NameUuidGen.d

/*******************************************************************************

        copyright:      Copyright (c) 2007 Max Samukha. All rights reserved

        license:        BSD style: $(LICENSE)

        authors:         Max Samukha

        With the functions in this module, UUIDs can be created from names
        that are unique within a name space.

        MD-5 or SHA-1 hashing algorithms can be used to generate a name-based UUID.
        If backward compatibility is not an issue, SHA-1 should be preferred.

        The functions are thread-safe.

        Examples:
----
auto uuid = newUuidSha1(NameSpaceUuids.url, "http://www.dsource.org");
----


*******************************************************************************/
module tango.scrapple.util.uuid.NameUuidGen;

public import tango.scrapple.util.uuid.Uuid;
import tango.io.digest.Sha1;
import tango.io.digest.Md5;

private Uuid newUuid(Uuid nsUuid, char[] name, Digest digest, UuidVersion ver)
{
    assert(name.length > 0);

    ubyte[16] nsOctets;
    nsUuid.toOctets(nsOctets);

    digest.update(nsOctets);
    digest.update(cast(ubyte[])name);

    Uuid uuid = digest.binaryDigest;
    uuid.versionTimeHigh = (uuid.versionTimeHigh & 0x0FFF) | (ver << 12);
    uuid.variantClockSeqHigh = (uuid.variantClockSeqHigh & 0x3F) | 0x80;

    return uuid;
}

/**
    Generates a _name-based UUID using SHA-1 hashing algorithm (version 5 UUID).

    Params:
        nsUuid  = namespace UUID.
        name    = _name from which to generate.

    Returns: The generated UUID.
*/
Uuid newUuidSha1(Uuid nsUuid, char[] name)
{
   scope digest = new Sha1();
   return newUuid(nsUuid, name, digest, UuidVersion.NameBasedSha1);
}

/**
    Generates a _name-based UUID using MD-5 hashing algorithm (version 3 UUID).

    Params:
        nsUuid  = namespace UUID.
        name    = name from which to generate.

    Returns: The generated UUID.
*/
Uuid newUuidMd5(Uuid nsUuid, char[] name)
{
   scope digest = new Md5();
   return newUuid(nsUuid, name, digest, UuidVersion.NameBasedMd5);
}

/**
    A subset of commonly used namespace UUIDs
*/
struct NameSpaceUuids
{
    static const
    {
        ///
        Uuid dns = { 0x6ba7b810, 0x9dad, 0x11d1, 0x80, 0xb4, [cast(ubyte)0x00, 0xc0, 0x4f, 0xd4, 0x30, 0xc8] };

        ///
        Uuid url = { 0x6ba7b811, 0x9dad, 0x11d1, 0x80,  0xb4, [cast(ubyte)0x00, 0xc0, 0x4f, 0xd4, 0x30, 0xc8] };

        ///
        Uuid oid = { 0x6ba7b812, 0x9dad, 0x11d1, 0x80, 0xb4, [cast(ubyte)0x00, 0xc0, 0x4f, 0xd4, 0x30, 0xc8] };

        ///
        Uuid x500 = { 0x6ba7b814, 0x9dad, 0x11d1, 0x80, 0xb4, [cast(ubyte)0x00, 0xc0, 0x4f, 0xd4, 0x30, 0xc8] };
    }
}

debug (UuidUnitTest)
{
    import tango.io.Stdout;

    unittest
    {
        const char[] TestUuidStr = "24bb3c5e-988b-4833-9d9a-77bf84b3284c";
        const char[] TestName = "TestUuidStr";

        Uuid nsUuid = TestUuidStr;

        // SHA-1
        auto uuid = newUuidSha1(nsUuid, TestName);
        auto uuid2 = newUuidSha1(nsUuid, TestName);

        assert(uuid == uuid2);
        assert(uuid.ver == UuidVersion.NameBasedSha1);
        assert(uuid.variant == UuidVariant.Standard);

        // MD5
        uuid = newUuidMd5(nsUuid, TestName);
        uuid2 = newUuidMd5(nsUuid, TestName);

        assert(uuid == uuid2);
        assert(uuid.ver == UuidVersion.NameBasedMd5);
        assert(uuid.variant == UuidVariant.Standard);


        // Namespace uuids
        assert (NameSpaceUuids.dns  == Uuid("6ba7b810-9dad-11d1-80b4-00c04fd430c8"));
        assert (NameSpaceUuids.url  == Uuid("6ba7b811-9dad-11d1-80b4-00c04fd430c8"));
        assert (NameSpaceUuids.oid  == Uuid("6ba7b812-9dad-11d1-80b4-00c04fd430c8"));
        assert (NameSpaceUuids.x500 == Uuid("6ba7b814-9dad-11d1-80b4-00c04fd430c8"));

    }
}