root/trunk/blade/BladeUtil.d

//  Written in the D programming language 1.0
/**
* General CTFE functions
* BLADE 0.3Alpha -- Basic Linear Algebra D Expressions
*/

module blade.BladeUtil;

public:

// Convert from integral type to string.
char [] itoa(T)(T x)
{
    char [] s="";
    static if (is(T==byte)||is(T==short)||is(T==int)||is(T==long)) {
        if (x<0) {
            return "-" ~ itoa(-x);
        }
    }
    do {
        s = cast(char)('0' + (x%10)) ~ s;
        x/=10;
    } while (x>0);
    return s;
}


unittest {
    assert(blade.BladeUtil.itoa(-5)=="-5");
}

/** Escape any quotes and backslashes inside the given string,
 * prefixing them with the given escape sequence. Use `\` to escape
 * once, `\\\` to escape twice.
 */
char [] enquote(char [] instr, char [] escape=`\`)
{
    // This function is critical for compilation speed.
    // Need to minimise the number of allocations.
    // It's worth using copy-on-write even for CTFE.
 
    for(int i=0; i<instr.length; ++i) {
        if (instr[i]=='"' || instr[i]=='\\') {
            char [] str = instr[0..i] ~ escape;
            int m = i;
            foreach(int k, char c; instr[i+1..$]) {
                if (c=='"' || c=='\\') {
                    str ~= instr[m..i+1+k] ~ escape;
                    m = i+k+1;
                }
            }
            return str ~ instr[m..$];
        }
    }    
    return instr;   
}

unittest {
    assert(enquote(`"a\"`)==`\"a\\\"`);
    assert(enquote(`abc`)==`abc`);
}