root/trunk/apufba/Apufba.d

/*
 Copyright (c) 2007, Carlos Santander Bernal

 This software is provided 'as/is', without any express or implied warranty. In
 no event will the authors be held liable for any damages arising from the use
 of this software.

 Permission is granted to anyone to use this software for any purpose, including
 commercial applications, and to alter it and redistribute it freely, subject to
 the following restrictions:

 1. The origin of this software must not be misrepresented; you must not
 claim that you wrote the original software. If you use this software in
 a product, an acknowledgment in the product documentation would be
 appreciated but is not required.

 2. Altered source versions must be plainly marked as such, and must not be
 misrepresented as being the original software.

 3. This notice may not be removed or altered from any source distribution.
 */
module apufba.Apufba;

import apufba.platf.LaunchBrowser;

import fbd.FacebookClient : FacebookClient, PropertyInfo;
import fbd.FacebookError : FacebookError;
import fbd.FacebookTypes : Album;
import fbd.FacebookUser : FacebookUser;

import tango.io.File : File;
import tango.io.FileConduit : FileConduit;
import tango.io.FilePath : FilePath;
import tango.net.http.HttpGet : HttpGet;
import tango.text.Util : locate, trim;
import tango.text.convert.Integer : toString;
import tango.text.stream.LineIterator : LineIterator;
import tango.util.log.Appender : Appender;
import tango.util.log.ConsoleAppender : ConsoleAppender;
import tango.util.log.Event : LogEvent = Event;
import tango.util.log.EventLayout : EventLayout;
import tango.util.log.Log : Log, Logger;

import wx.wx;

int main (char[][] args)
{
    auto app = new ApufbaApp ();
    app.Run ();
    return 0;
}

private const ApplicationTitle = "Apufba";

class ApufbaApp : App
{
    override bool OnInit ()
    {
        char[] apikey, secret;

        try
        {
            /*
             'account' should be:
             API Key:       your-api-key
             Secret:    your-secret
             */
            auto account = new FileConduit ("account");
            auto it = new LineIterator!(char) (account);

            char[] tmp = it.next ();
            auto pos = locate (tmp, ':');
            apikey = trim (tmp[pos + 1 .. $]);

            tmp = it.next ();
            pos = locate (tmp, ':');
            secret = trim (tmp[pos + 1 .. $]);
        }
        catch (Exception e)
        {
            MessageBox (e.toString, ApplicationTitle,
                Dialog.wxOK | Dialog.wxCENTRE | Dialog.wxICON_ERROR);
            return false;
        }

        try
        {
            auto fbclient = new FacebookClient (apikey, secret);

            auto frame = new ApufbaFrame (this, fbclient);
            log = new LogFrame (frame);
            frame.Show (true);
            log.Show (true);

            log.logger.info ("API Key: " ~ apikey);
            log.logger.info ("Secret: " ~ secret);
        }
        catch (Object o)
            MessageBox (o.toString, ApplicationTitle,
                Dialog.wxOK | Dialog.wxCENTRE | Dialog.wxICON_ERROR);

        return true;
    }

    LogFrame log;
}

class ApufbaFrame : Frame
{
    this (ApufbaApp app, FacebookClient client)
    {
        super (ApplicationTitle, wxDefaultPosition, Size (600, 600));
        this.app = app;
        fbclient = client;

        version (Windows)
        {
            BackgroundColour = SystemSettings.GetColour (
                SystemColour.wxSYS_COLOUR_BTNFACE);
        }

        top = new Panel (this, wxDefaultPosition, Size (600, 50));
        content = new Panel (this, Point (0, 50), Size (600, 550));
        auto boxSizer = new BoxSizer (Orientation.wxVERTICAL);
        boxSizer.Add (top, Alignment.wxALIGN_TOP);
        boxSizer.Add (content, Stretch.wxEXPAND);
        sizer = boxSizer;

        list = new ListBox (content, Point (8, 8), Size (150, 550));
        with (list)
        {
            Append ("My profile");
            Append ("Friends");
            Append ("Notifications");
            Append ("Photos");
            SetSelection (0, true);
            Select_Add (&selectView);
        }

        main = new Panel (content, wxDefaultPosition, Size (400, 400));
        boxSizer = new BoxSizer (Orientation.wxHORIZONTAL);
        boxSizer.Add (list, Alignment.wxALIGN_LEFT);
        boxSizer.AddSpacer (8);
        boxSizer.Add (main, Stretch.wxEXPAND);
        content.sizer = boxSizer;
        boxSizer.Layout ();
        content.Hide ();

        auto st = new StaticText (top,
            "You need to log in to Facebook to start using Apufba",
            Point (8, 8));
        auto login = new Button (top, "Log in", Point (st.Right + 8, st.Top));
        login.Click_Add (&logIn);

        size (BestSize ());
        CenterOnScreen ();
    }

    void logIn (Object sender, Event e)
    {
        fbclient.authenticate ();

        auto loginurl = fbclient.loginURL ();
        app.log.logger.info ("Login URL: " ~ loginurl);

        launchBrowser (loginurl);
        MessageBox (
            this,
            "A browser window has been launched.\nAfter logging in to Facebook, click Ok to continue.",
            ApplicationTitle);

        fbclient.getSession ();
        auto user = fbclient.getThisUserInfo (FacebookUser.Fields.NAME);

        top.DestroyChildren ();
        new StaticText (top, "Welcome, " ~ user.name ~ "!", Point (8, 8));
        content.Show ();

        profileView ();

        size (BestSize ());
        CenterOnScreen ();
    }

    void selectView (Object sender, Event e)
    {
        main.DestroyChildren ();

        switch ((cast(CommandEvent) e).Selection)
        {
            case 0:
                // profile
                profileView ();
                break;
            case 1:
                // friends
                friendsView ();
                break;
            case 2:
                // notifications
                notificationsView ();
                break;
            case 3:
                // photos
                photosView ();
                break;
            default:
        }
    }

    void profileView ()
    {
        app.log.logger.info ("getting user profile");
        auto user = fbclient.getThisUserInfo (FacebookUser.Fields.BIRTHDAY,
            FacebookUser.Fields.ABOUT_ME, FacebookUser.Fields.PIC_BIG);
        new StaticText (main, "Birthday: " ~ user.birthday, Point (8, 8));
        new StaticText (main, "About me: " ~ user.aboutMe, Point (8, 32), Size (
            300, 160));

        insertImage (user.picBig, main, Point (8, 240));
    }

    void friendsView ()
    {
    }

    void notificationsView ()
    {
    }

    void photosView ()
    {
        app.log.logger.info ("getting albums");
        albums = fbclient.getThisUserAlbums ();

        if (albums.length == 0)
        {
            new StaticText (main, "You don't have any albums!", Point (8, 8));
            return;
        }

        with (new Choice (main, Point (8, 8), wxDefaultSize))
        {
            Selected_Add (&changeAlbum);
            foreach (alb; albums)
                Append (alb.name);
            Selection = 0;
        }
    }

    void changeAlbum (Object sender, Event e)
    {
        app.log.logger.info ("getting one photo");
        auto photos = fbclient.getPhotosById (
            albums[(cast(CommandEvent) e).Selection].coverPhotoId);
        insertImage (photos[0].bigSrc, main, Point (8, 100));
    }

    void insertImage (char[] url, Panel where, Point pos)
    {
        app.log.logger.info (url);
        auto f = (new FilePath (url)).file;
        (new File (f)).write ((new HttpGet (url)).read);
        app.log.logger.info ("image: " ~ f);

        scope pic = new Bitmap (new Image (f));
        app.log.logger.info (
            "dimensions: " ~ .toString (pic.Width) ~ "," ~ .toString (
                pic.Height));
        new StaticBitmap (where, pic, pos, Size (pic.Width, pic.Height));

        (new FilePath (f)).remove ();
    }

    ApufbaApp app;
    FacebookClient fbclient;
    Panel top, content, main;
    ListBox list;
    Album[] albums;
}

class LogFrame : Frame
{
    this (Frame parent)
    {
        super (parent, "Log", wxDefaultPosition, Size (
            SystemSettings.GetMetric (SystemMetric.wxSYS_SCREEN_X), 200));
        auto logList = new ListBox (this);
        auto f = new Font ();
        version (darwin)
        {
            f.FaceName = "Monaco";
            f.PointSize = 9;
        }
        else version (Windows)
        {
            f.FaceName = "Lucida Console";
            f.PointSize = 9;
        }
        logList.SetFont (f);
        logger = Log.getLogger ("apufba");
        logger.addAppender (new ListBoxAppender (logList));
        logger.addAppender (new ConsoleAppender ());
    }

    Logger logger;
}

// based on ConsoleAppender
class ListBoxAppender : Appender
{
    private Mask mask;
    private ListBox list;

    this (ListBox list, EventLayout layout = null)
    {
        mask = register (getName);
        setLayout (layout);
        this.list = list;
    }

    override Mask getMask ()
    {
        return mask;
    }

    override char[] getName ()
    {
        return this.classinfo.name;
    }

    override void append (LogEvent event)
    {
        synchronized (list)
        {
            auto layout = getLayout;
            list.Append (
                layout.header (event) ~ layout.content (event) ~ layout.footer (
                    event));
        }
    }
}