root/branches/0.2/controlexample/tabletreetab.d

/*******************************************************************************
 * Copyright (c) 2000, 2003 IBM Corporation and others.
 * All rights reserved. This program and the accompanying materials 
 * are made available under the terms of the Common Public License v1.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/cpl-v10.html
 * 
 * Contributors:
 *     IBM Corporation - initial API and implementation
 *******************************************************************************/
module controlexample.tabletreetab;

private {
import swt.all;
import controlexample.scrollabletab;
import controlexample.controlexample;
}


class TableTreeTab : ScrollableTab {
    /* Example widgets and groups that contain them */
    TableTree tree1;
    TableTreeItem node1;
    Group treeGroup, itemGroup;
    
    /* Style widgets added to the "Style" group */
    Button checkButton, fullSelectionButton;
    
    /* Controls and resources added to the "Colors" group */
    Button itemForegroundButton, itemBackgroundButton, itemFontButton;
    Color itemForegroundColor, itemBackgroundColor;
    Image itemForegroundImage, itemBackgroundImage;
    Font itemFont;
    
    /* Other widgets added to the "Other" group */
    Button headerVisibleButton, linesVisibleButton;

    /**
     * Creates the Tab within a given instance_ren of ControlExample.
     */
    this(ControlExample instance_ren) {
        super(instance_ren);
    }
    
    /**
     * Creates the "Colors" group.
     */
    void createColorGroup () {
        super.createColorGroup();
        
        itemGroup = new Group (colorGroup, SWT.NONE);
        itemGroup.setText (ControlExample.getResourceString ("Tree_Item_Colors"));
        GridData data = new GridData ();
        data.horizontalSpan = 2;
        itemGroup.setLayoutData (data);
        itemGroup.setLayout (new GridLayout (2, false));
        Label label = new Label (colorGroup, SWT.NONE);
        label.setText (ControlExample.getResourceString ("Foreground_Color"));
        itemForegroundButton = new Button (itemGroup, SWT.PUSH);
        label = new Label (colorGroup, SWT.NONE);
        label.setText (ControlExample.getResourceString ("Background_Color"));
        itemBackgroundButton = new Button (itemGroup, SWT.PUSH);
        itemFontButton = new Button (itemGroup, SWT.PUSH);
        itemFontButton.setText(ControlExample.getResourceString("Font"));
        itemFontButton.setLayoutData(new GridData (GridData.HORIZONTAL_ALIGN_FILL));
        
        Shell shell = colorGroup.getShell ();
        
        int imageSize = 12;
        Display display = shell.getDisplay ();
        itemForegroundImage = new Image(display, imageSize, imageSize);
        itemBackgroundImage = new Image(display, imageSize, imageSize);

        /* Add listeners to set the colors and font */
        itemForegroundButton.setImage(itemForegroundImage);
        itemForegroundButton.handleSelection(this, delegate(SelectionEvent event) {
            TableTreeTab c = cast(TableTreeTab)event.cData;
            Color oldColor = c.itemForegroundColor;
            if (oldColor is null) oldColor = c.node1.getForeground ();
            ColorDialog foregroundDialog = new ColorDialog (c.colorGroup.getShell());
            foregroundDialog.setRGB(oldColor.getRGB());
            RGB rgb = foregroundDialog.open();
            if (rgb is null) return;
            oldColor = c.itemForegroundColor;
            c.itemForegroundColor = new Color (event.display, rgb);
            c.setItemForeground ();
            if (oldColor !== null) oldColor.dispose ();
        });
        itemBackgroundButton.setImage(itemBackgroundImage);
        itemBackgroundButton.handleSelection(this, delegate(SelectionEvent event) {
            TableTreeTab c = cast(TableTreeTab)event.cData;
            Color oldColor = c.itemBackgroundColor;
            if (oldColor is null) oldColor = c.node1.getBackground ();
            ColorDialog backgroundDialog = new ColorDialog (c.colorGroup.getShell());
            backgroundDialog.setRGB(oldColor.getRGB());
            RGB rgb = backgroundDialog.open();
            if (rgb is null) return;
            oldColor = c.itemBackgroundColor;
            c.itemBackgroundColor = new Color (event.display, rgb);
            c.setItemBackground ();
            if (oldColor !== null) oldColor.dispose ();
        });
        itemFontButton.handleSelection(this, delegate(SelectionEvent event) {
            TableTreeTab c = cast(TableTreeTab)event.cData;
            Font oldFont = c.itemFont;
            if (oldFont is null) oldFont = c.node1.getFont ();
            FontDialog fontDialog = new FontDialog (c.colorGroup.getShell());
            fontDialog.setFontList(oldFont.getFontData());
            FontData fontData = fontDialog.open ();
            if (fontData is null) return;
            oldFont = c.itemFont;
            c.itemFont = new Font (event.display, fontData);
            c.setItemFont ();
            c.setExampleWidgetSize ();
            if (oldFont !== null) oldFont.dispose ();
        });
        shell.handleDispose(this, delegate(DisposeEvent event) {
            TableTreeTab c = cast(TableTreeTab)event.cData;
            if (c.itemBackgroundImage !== null) c.itemBackgroundImage.dispose();
            if (c.itemForegroundImage !== null) c.itemForegroundImage.dispose();
            if (c.itemBackgroundColor !== null) c.itemBackgroundColor.dispose();
            if (c.itemForegroundColor !== null) c.itemForegroundColor.dispose();
            if (c.itemFont !== null) c.itemFont.dispose();
            c.itemBackgroundColor = null;
            c.itemForegroundColor = null;           
            c.itemFont = null;
        });
    }

    /**
     * Creates the "Other" group.
     */
    void createOtherGroup () {
        super.createOtherGroup ();
    
        /* Create display controls specific to this example */
        headerVisibleButton = new Button (otherGroup, SWT.CHECK);
        headerVisibleButton.setText (ControlExample.getResourceString("Header_Visible"));
        linesVisibleButton = new Button (otherGroup, SWT.CHECK);
        linesVisibleButton.setText (ControlExample.getResourceString("Lines_Visible"));
    
        /* Add the listeners */
        headerVisibleButton.handleEvent(this, SWT.Selection, &setWidgetHeaderVisible);
        linesVisibleButton.handleEvent(this, SWT.Selection, &setWidgetLinesVisible);
    }

    /**
     * Creates the "Example" group.
     */
    void createExampleGroup () {
        super.createExampleGroup ();
        
        /* Create a group for the text tree */
        treeGroup = new Group (exampleGroup, SWT.NONE);
        treeGroup.setLayout (new GridLayout ());
        treeGroup.setLayoutData (new GridData (GridData.GRAB_HORIZONTAL | GridData.HORIZONTAL_ALIGN_FILL | GridData.VERTICAL_ALIGN_FILL));
        treeGroup.setText ("TableTree");
    }
    
    /**
     * Creates the "Example" widgets.
     */
    void createExampleWidgets () {
        /* Compute the widget style */
        int style = getDefaultStyle();
        if (singleButton.getSelection()) style |= SWT.SINGLE;
        if (multiButton.getSelection()) style |= SWT.MULTI;
        if (checkButton.getSelection()) style |= SWT.CHECK;
        if (borderButton.getSelection()) style |= SWT.BORDER;
        if (fullSelectionButton.getSelection()) style |= SWT.FULL_SELECTION;
    
        /* Create the text tree */
        tree1 = new TableTree (treeGroup, style);
        Table table = tree1.getTable();
        for (int i = 0; i < 3; i++) {
            TableColumn column = new TableColumn (table,SWT.NONE);
            column.setWidth(100);
            column.setText(ControlExample.getResourceString("TableTree_column") ~ ": " ~ std.string.toString(i));
        }
        node1 = new TableTreeItem (tree1, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node1.setText (i, ControlExample.getResourceString("Node_1") ~ "-" ~ std.string.toString(i));
        }
        node1.setImage (instance_ren.images[ControlExample.ciOpenFolder]);
        TableTreeItem node2 = new TableTreeItem (tree1, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node2.setText (i, ControlExample.getResourceString("Node_2") ~ "-" ~ std.string.toString(i));
        }
        node2.setImage (instance_ren.images[ControlExample.ciClosedFolder]);
        TableTreeItem node3 = new TableTreeItem (tree1, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node3.setText (i, ControlExample.getResourceString("Node_3") ~ "-" ~ std.string.toString(i));
        }
        node3.setImage (instance_ren.images[ControlExample.ciTarget]);
        TableTreeItem node4 = new TableTreeItem (tree1, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node4.setText (i, ControlExample.getResourceString("Node_4") ~ "-" ~ std.string.toString(i));
        }
        node4.setImage (instance_ren.images[ControlExample.ciOpenFolder]);
        TableTreeItem node1_1 = new TableTreeItem (node1, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node1_1.setText (i, ControlExample.getResourceString("Node_1_1") ~ "-" ~ std.string.toString(i));
        }
        node1_1.setImage (instance_ren.images[ControlExample.ciClosedFolder]);
        TableTreeItem node2_1 = new TableTreeItem (node2, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node2_1.setText (i, ControlExample.getResourceString("Node_2_1") ~ "-" ~ std.string.toString(i));
        }
        node2_1.setImage (instance_ren.images[ControlExample.ciTarget]);
        TableTreeItem node3_1 = new TableTreeItem (node3, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node3_1.setText (i, ControlExample.getResourceString("Node_3_1") ~ "-" ~ std.string.toString(i));
        }
        node3_1.setImage (instance_ren.images[ControlExample.ciOpenFolder]);
        TableTreeItem node2_2 = new TableTreeItem (node2, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node2_2.setText (i, ControlExample.getResourceString("Node_2_2") ~ "-" ~ std.string.toString(i));
        }
        node2_2.setImage (instance_ren.images[ControlExample.ciClosedFolder]);
        TableTreeItem node2_2_1 = new TableTreeItem (node2_2, SWT.NONE);
        for (int i = 0; i < 3; i++) {
            node2_2_1.setText (i, ControlExample.getResourceString("Node_2_2_1") ~ "-" ~ std.string.toString(i));
        }
        node2_2_1.setImage (instance_ren.images[ControlExample.ciTarget]);
    }
    
    /**
     * Creates the "Style" group.
     */
    void createStyleGroup() {
        super.createStyleGroup();
        
        /* Create the extra widgets */
        checkButton = new Button (styleGroup, SWT.CHECK);
        checkButton.setText ("SWT.CHECK");
        fullSelectionButton = new Button (styleGroup, SWT.CHECK);
        fullSelectionButton.setText ("SWT.FULL_SELECTION");
    }
    
    /**
     * Creates the tab folder page.
     *
     * @param tabFolder org.eclipse.swt.widgets.TabFolder
     * @return the new page for the tab folder
     */
    Composite createTabFolderPage (TabFolder tabFolder) {
        super.createTabFolderPage (tabFolder);

        /*
         * Add a resize listener to the tabFolderPage so that
         * if the user types into the example widget to change
         * its preferred size, and then resizes the shell, we
         * recalculate the preferred size correctly.
         */
        tabFolderPage.handleEvent(this, SWT.Resize, &setExampleWidgetSize);
        
        return tabFolderPage;
    }

    /**
     * Gets the "Example" widget children's items, if any.
     *
     * @return an array containing the example widget children's items
     */
    Item [] getExampleWidgetItems () {
        return tree1.getItems();
    }
    
    /**
     * Gets the "Example" widget children.
     */
    Control [] getExampleWidgets () {
        Control [] controls;
        controls ~= tree1;
        return controls;
    }
    
    /**
     * Gets the text for the tab folder item.
     */
    String getTabText () {
        return "TableTree";
    }

    /**
     * Sets the foreground color, background color, and font
     * of the "Example" widgets to their default settings.
     * Also sets foreground and background color of the Node 1
     * TreeItems to default settings.
     */
    void resetColorsAndFonts () {
        super.resetColorsAndFonts ();
        Color oldColor = itemForegroundColor;
        itemForegroundColor = null;
        setItemForeground ();
        if (oldColor !== null) oldColor.dispose();
        oldColor = itemBackgroundColor;
        itemBackgroundColor = null;
        setItemBackground ();
        if (oldColor !== null) oldColor.dispose();
        Font oldFont = font;
        itemFont = null;
        setItemFont ();
        setExampleWidgetSize ();
        if (oldFont !== null) oldFont.dispose();
    }
    
    /**
     * Sets the state of the "Example" widgets.
     */
    void setExampleWidgetState () {
        super.setExampleWidgetState ();
        setItemBackground ();
        setItemForeground ();
        setItemFont ();
        setExampleWidgetSize ();
        setWidgetHeaderVisible ();
        setWidgetLinesVisible ();
    }
    
    /**
     * Sets the background color of the Node 1 TreeItems.
     */
    void setItemBackground () {
        node1.setBackground (itemBackgroundColor);
        /* Set the background button's color to match the color just set. */
        Color color = itemBackgroundColor;
        if (color is null) color = node1.getBackground ();
        drawImage (itemBackgroundImage, color);
        itemBackgroundButton.setImage (itemBackgroundImage);
    }
    
    /**
     * Sets the foreground color of the Node 1 TreeItems.
     */
    void setItemForeground () {
        node1.setForeground (itemForegroundColor);
        /* Set the foreground button's color to match the color just set. */
        Color color = itemForegroundColor;
        if (color is null) color = node1.getForeground ();
        drawImage (itemForegroundImage, color);
        itemForegroundButton.setImage (itemForegroundImage);
    }
    
    /**
     * Sets the font of the Node 1 TreeItems.
     */
    void setItemFont () {
        if (instance_ren.startup) return;
        node1.setFont (itemFont);
    }

    /**
     * Sets the header visible state of the "Example" widgets.
     */
    void setWidgetHeaderVisible () {
        tree1.getTable().setHeaderVisible (headerVisibleButton.getSelection ());
    }
    
    /**
     * Sets the lines visible state of the "Example" widgets.
     */
    void setWidgetLinesVisible () {
        tree1.getTable().setLinesVisible (linesVisibleButton.getSelection ());
    }
}