root/branches/tango/sss/uninstall.d

/**
 * DSSS command "uninstall"
 * 
 * Authors:
 *  Gregor Richards
 * 
 * License:
 *  Copyright (c) 2006, 2007  Gregor Richards
 *  
 *  Permission is hereby granted, free of charge, to any person obtaining a
 *  copy of this software and associated documentation files (the "Software"),
 *  to deal in the Software without restriction, including without limitation
 *  the rights to use, copy, modify, merge, publish, distribute, sublicense,
 *  and/or sell copies of the Software, and to permit persons to whom the
 *  Software is furnished to do so, subject to the following conditions:
 *  
 *  The above copyright notice and this permission notice shall be included in
 *  all copies or substantial portions of the Software.
 *  
 *  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 *  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 *  FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 *  AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 *  LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
 *  FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
 *  DEALINGS IN THE SOFTWARE.
 */

module sss.uninstall;

import tango.io.Console;
import tango.io.File;
import tango.io.FileConst;
import tango.io.FilePath;
import tango.io.FileSystem;

import tango.text.Util;

import sss.clean;
import sss.conf;

import hcf.path;

/** Entry to the "uninstall" function */
int uninstall(char[][] toolList, bool quiet = false)
{
    if (toolList.length == 0) {
        Cout("Uninstall what?").newline;
        return 1;
    }
    
    foreach (tool; toolList)
    {
        // uninstall this tool
        char[] manifestFile = manifestPrefix ~ FileConst.PathSeparatorChar ~ tool ~ ".manifest";
        if (!(new FilePath(manifestFile)).exists()) {
            if (!quiet)
                Cout("Tool ")(tool)(" is not installed.").newline;
            return 1;
        }
        
        Cout("Uninstalling ")(tool).newline;
        
        // get the list
        char[][] manifest = split(
            cast(char[]) (new File(manifestFile)).read(),
            "\n");
        
        // then delete them
        foreach (filen; manifest) {
            if (filen == "") continue;
            
            auto file = new FilePath(filen);
            
            // if it's not absolute, infer the absolute path
            if (!file.isAbsolute()) {
                file = new FilePath(forcePrefix ~ FileConst.PathSeparatorChar ~ filen);
                cleanTree(file.path());
            }
            
            Cout("Removing ")(file).newline;
            tryRemove(file.toUtf8());
        }
        
        Cout.newline;
    }
    
    return 0;
}

/** Entry to the "installed" function */
int installed()
{
    auto manifests = new FilePath(manifestPrefix);
    foreach (pkg; manifests.toList((FilePath p, bool b) { return true; }).sort)
    {
        if (pkg.name.length < 9 || pkg.name[$-9 .. $]  != ".manifest") continue;
        auto pkgName = pkg.name[0 .. $-9];
        
        Cout(pkgName).newline;
    }
    
    return 0;
}