root/trunk/UWsConfigDlg.pas

unit UWsConfigDlg;

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls, Workspaces, Dialogs;

type
  TwsConfigDlg = class(TForm)
    SaveButton: TButton;
    CancelButton: TButton;
    Bevel1: TBevel;
    Label1: TLabel;
    Label2: TLabel;
    compilerPath: TEdit;
    Label3: TLabel;
    linkerPath: TEdit;
    editorPath: TEdit;
    ImportButton: TButton;
    Label4: TLabel;
    editorCommand: TEdit;
    BrowseCompiler: TButton;
    BrowseLinker: TButton;
    BrowseEditor: TButton;
    defaultCheckbox: TCheckBox;
    Label5: TLabel;
    name: TEdit;
    FileDialog: TOpenDialog;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure SaveButtonClick(Sender: TObject);
    procedure BrowseCompilerClick(Sender: TObject);
    procedure BrowseLinkerClick(Sender: TObject);
    procedure BrowseEditorClick(Sender: TObject);
    procedure ImportButtonClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    isnew : boolean;
    importPaths : TStringList;
    procedure SaveOptions( ws : TWorkspace );
    procedure LoadOptions( ws : TWorkspace );
  end;

var
  wsConfigDlg: TwsConfigDlg;

implementation

{$R *.DFM}

uses MyUtils,FileCtrl, UImportList;

procedure TWSConfigDlg.SaveOptions( ws : TWorkspace );
begin
  ws.config.compiler := compilerPath.Text;
  ws.config.linker := linkerPath.Text;
  ws.config.sourceEditor := editorPath.Text;
  ws.name := name.Text;
  ws.config.editorCommand := Self.editorCommand.Text;
  ws.config.paths.Clear;
  ws.config.paths.AddStrings( Self.importPaths );
end;

procedure TWSConfigDlg.LoadOptions( ws : TWorkspace );
begin
  if Empty( ws.filename ) then Caption:='Configure New Workspace'
  else Caption:='Configuration for:  ' + ws.filename; 

  compilerPath.Text := ws.config.compiler;
  linkerPath.Text := ws.config.linker;
  editorPath.Text := ws.config.sourceEditor;
  editorCommand.Text := ws.config.editorCommand;
  Self.name.Text := ws.name;
  Self.importPaths.Clear;
  Self.importPaths.AddStrings( ws.config.paths );
end;

procedure TwsConfigDlg.FormCreate(Sender: TObject);
begin
  importPaths := TStringList.Create;
end;

procedure TwsConfigDlg.FormDestroy(Sender: TObject);
begin
  importPaths.Free;
end;

procedure TwsConfigDlg.SaveButtonClick(Sender: TObject);
begin
  if Length( name.Text )<1 then begin
    Application.MessageBox( PChar('You Must Enter a Workspace Name!'),
                            'Error', MB_OK );
    Exit;
  end  ;
  Self.ModalResult := mrOk;
end;


function  GetParentDir( Path : string ; num : Integer ) : string;
var
  N : Integer;
begin
  while Path[ Length(Path) ] in [ '/', '\' ] do Path:= Copy( Path, 1, Length(Path)-1 );

  while num > 0 do begin
    Dec( num );
    N := LastDelimiter( '/\', Path );
    if N < 1 then Exit;
    Path := Copy( Path, 1, N-1 );
  end;
  Result := Path + '\';
end;

procedure TwsConfigDlg.BrowseCompilerClick(Sender: TObject);
var
  DMD : string;
  LINK : string;
begin
  //FileDialog.InitialDir := defaultWS.compiler;
  FileDialog.Title := 'Select DMD compiler (dmd.exe)';
  FileDialog.Filter := 'Executable files|*.exe';
  FileDialog.Options := [ofPathMustExist , ofFileMustExist];

  if FileDialog.Execute = false then Exit;
  if FileDialog.Files.Count < 1 then Exit;
  DMD := Trim( FileDialog.Files[0] );
  compilerPath.Text := DMD;

  if Length( Trim(linkerPath.Text) ) = 0 then begin
    LINK := GetParentDir( ExtractFilePath(DMD), 2 );
    LINK := Path( LINK, '\dm\bin\link.exe' );
    if FileExists( LINK ) then linkerPath.Text:= LINK;
  end;
end;

procedure TwsConfigDlg.BrowseLinkerClick(Sender: TObject);
var
  DMD : string;
  LINK : string;
begin
  FileDialog.Title := 'Select DMD linker (link.exe)';
  FileDialog.Filter := 'Executable files|*.exe';
  FileDialog.Options := [ofPathMustExist , ofFileMustExist];

  if FileExists( compilerPath.Text ) then
    FileDialog.InitialDir:= GetParentDir( compilerPath.Text, 2) + 'dm\bin';
  if FileDialog.Execute = false then Exit;
  if FileDialog.Files.Count < 1 then Exit;
  LINK := Trim( FileDialog.Files[0] );
  linkerPath.Text := LINK;

  if Length( Trim(compilerPath.Text) ) = 0 then begin
    DMD := GetParentDir( ExtractFilePath(LINK), 2 );
    DMD := Path( DMD, '\dmd\bin\dmd.exe' );
    if FileExists( DMD ) then compilerPath.Text:= DMD;
  end ;
end;


procedure TwsConfigDlg.BrowseEditorClick(Sender: TObject);
var
  D : string;
begin
  //FileDialog.InitialDir := homedir;
  FileDialog.Title := 'Select Source Editor';
  FileDialog.Filter := 'Executable files|*.exe';
  FileDialog.Options := [ofPathMustExist , ofFileMustExist];

  if FileDialog.Execute = false then Exit;
  if FileDialog.Files.Count < 1 then Exit;
  D := Trim( FileDialog.Files[0] );
  editorPath.Text := D;
end;

procedure TwsConfigDlg.ImportButtonClick(Sender: TObject);
begin
  PathDialog.PathListbox.Items.Clear;
  PathDialog.PathListbox.Items.AddStrings( Self.importPaths );
  if PathDialog.ShowModal <> mrOK then Exit;
  Self.importPaths.Clear;
  Self.importPaths.AddStrings( PathDialog.PathListbox.Items );
end;

end.