root/trunk/UProjConfigDlg.pas

unit UProjConfigDlg;

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls, Projects;

type
  TProjConfigDlg = class(TForm)
    SaveButton: TButton;
    CancelButton: TButton;
    Bevel1: TBevel;
    Label1: TLabel;
    Label2: TLabel;
    GroupBox1: TGroupBox;
    optimize: TCheckBox;
    debug: TCheckBox;
    debugsym: TCheckBox;
    profiling: TCheckBox;
    name: TEdit;
    outfilename: TEdit;
    unittests: TCheckBox;
    inlining: TCheckBox;
    Label3: TLabel;
    outputPath: TEdit;
    BrowseOutput: TButton;
    ImportPathButton: TButton;
    Label4: TLabel;
    versionNumber: TEdit;
    defaultCheckbox: TCheckBox;
    projectPath: TEdit;
    Label5: TLabel;
    BrowseProject: TButton;
    LinkerButton: TButton;    
    releaseVer: TCheckBox;
    VersionsButton: TButton;
    procedure SaveButtonClick(Sender: TObject);
    procedure BrowseProjectClick(Sender: TObject);
    procedure BrowseOutputClick(Sender: TObject);
    procedure VersionsButtonClick(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure ImportPathButtonClick(Sender: TObject);
    procedure LinkerButtonClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    projDir : string;
    versions : TStringList ;
    importPaths :TStringList;
    linkerFlags :TStringList;
    procedure SaveOptions( proj: TProject );
    procedure LoadOptions( proj: TProject );
    function  Validate(var S : string) : boolean;
  end;

var
  ProjConfigDlg: TProjConfigDlg;

implementation

{$R *.DFM}

uses MyUtils, FileCtrl, UVersionList, UImportList, ULinkerList;



procedure TProjConfigDlg.SaveOptions( proj :TProject );
var
  config : TProjectCfg;
  I,N : Integer;
begin
  proj.name := Self.name.text;
  proj.destfilename := ExtractFileName( outfilename.Text );  
  proj.outPath := outputPath.Text;
  proj.basepath := projectPath.Text;

  config := proj.config;
  config.versions.Clear;
  config.versions.AddStrings( versions );

  for N:=0 to versions.Count-1 do begin
    I := proj.enabled.IndexOf( versions[N] );
    if I>=0 then proj.enabled.Delete(I);
  end;

  proj.importPaths.Clear;
  proj.importPaths.AddStrings( Self.importPaths );

  config.linkerFlags.Clear;
  config.linkerFlags.AddStrings( self.linkerFlags );

  config.optimize := optimize.Checked;
  config.inlineFn := inlining.Checked;
  config.debugVersion := debug.Checked;
  config.debugSymbols := debugsym.Checked;
  config.profileHooks := profiling.Checked;
  config.unittests := unittests.Checked;
  config.releaseVersion := releaseVer.Checked;
  config.versionNumber := versionNumber.Text;
end;

procedure TProjConfigDlg.LoadOptions( proj : TProject );
begin
  if Empty( proj.filename ) then Caption:='New Project'
  else Caption:='Configuration for:  ' + proj.filename; 

  name.Text := proj.name;
  outfilename.Text := proj.destfilename ;  
  outputPath.Text := proj.outPath ;
  projectPath.Text := proj.basepath;

  Self.versions.Clear;
  Self.versions.AddStrings( proj.config.versions );

  Self.importPaths.Clear;
  Self.importPaths.AddStrings( proj.importPaths );

  Self.linkerFlags.Clear;
  Self.LinkerFlags.AddStrings( proj.config.linkerflags );

  self.versionNumber.Text := proj.config.versionNumber;
  with proj do begin
    optimize.Checked := config.optimize ;
    inlining.Checked := config.inlineFn ;
    debug.Checked := config.debugVersion ;
    debugsym.Checked := config.debugSymbols ;
    profiling.Checked := config.profileHooks ;
    unittests.Checked := config.unittests ;
    releaseVer.Checked := config.releaseVersion;
  end;
end;


function ConfirmCreate( name, dir : string ) : boolean ;
var
  msg : string;
begin
  Result := false;
  dir := Trim( dir );
  if Length( dir )= 0 then begin
    Application.MessageBox( PChar('Please enter a ' + name) , 'Input required', MB_OK ); 
    Exit;
  end;

  msg :=  name + ' does not exist! Create this directory?\nClick No to cancel';
  if Application.MessageBox( PChar( msg ), 'Confirm', MB_YESNO ) = IDNO then Exit;
  Result:= ForceDirectories( dir );
end;


function TProjConfigDlg.Validate( var S: string ) : boolean ;
var
   V:Integer;
begin
  Result:= false;
  if Length( Self.name.Text )<1 then begin
    S := 'You must name this project' ;
    self.name.SetFocus;
    Exit;
  end;

  If DirectoryExists( Self.projectPath.Text ) = false then begin
    S := 'That project directory does not exist';
    projectPath.SetFocus;
    Exit;
  end;

  if ( Pos( ' ', outfilename.Text )>0 ) or ( Length(outfilename.text)<1 ) then
  begin
    S := 'Output filename must be a valid filename';
    outfilename.SetFocus;
    Exit;
  end;

  if Find( outfilename.Text, '/\:;| ' )>0 then
  begin
    S := 'Invalid Output Filename, It must be a valid filename.';
    outfilename.SetFocus;
    Exit;
  end;

  if not Empty( versionNumber.Text ) then
   if ParseInt( versionNumber.Text, V ) = false then
   begin
     S := 'Invalid Version Number';
     versionNumber.SetFocus;
     Exit;
   end;

  result:= true;
end;


procedure TProjConfigDlg.SaveButtonClick(Sender: TObject);
var
  msg:string ;
begin
  name.Text := Trim( Name.Text );
  outfilename.Text := Trim( outfilename.Text );

  if not Validate( msg ) then begin
    Application.MessageBox( PChar(Msg), 'Error', MB_OK );
    Exit;
  end;

  If not DirectoryExists( Self.projectPath.Text ) then begin
    if not ConfirmCreate( 'Project directory', projectPath.Text ) then Exit;
  end;

  if not DirectoryExists( Self.outputPath.Text ) then begin
    if not ConfirmCreate( 'Output path', outputPath.Text ) then Exit;
  end;

  Self.ModalResult := mrOk
end;

procedure TProjConfigDlg.BrowseProjectClick(Sender: TObject);
var
  D : string;
begin
  D := Self.projDir ;
  if not DirectoryExists(D) then D:=GetCurrentDir;
  if SelectDirectory( D, [sdAllowCreate], 0 ) then begin
    projectPath.Text := D;
    D := Trim( outputPath.Text );
    if Length(D) = 0 then outputPath.Text := projectPath.Text;
    Exit;
  end;
end;

procedure TProjConfigDlg.BrowseOutputClick(Sender: TObject);
var
  D : string;
begin
  D := projDir ;
  if SelectDirectory( D, [sdAllowCreate], 0 ) then begin
    outputPath.Text := D;
    D := Trim( projectPath.Text );
    if Length(D) = 0 then projectPath.Text := outputPath.Text;
    Exit;
  end;
end;


procedure TProjConfigDlg.VersionsButtonClick(Sender: TObject);
begin
   VersionDialog.EditList( versions );
end;

procedure TProjConfigDlg.FormDestroy(Sender: TObject);
begin
  versions.Free;
  importPaths.Free;
  linkerflags.Free;
end;

procedure TProjConfigDlg.FormCreate(Sender: TObject);
begin
  Self.versions := TStringList.Create;
  Self.ImportPaths := TStringList.Create;
  Self.LinkerFlags := TStringList.Create;
end;

procedure TProjConfigDlg.ImportPathButtonClick(Sender: TObject);
begin
  PathDialog.PathListbox.Items.Clear;
  PathDialog.PathListbox.Items.AddStrings( Self.importPaths );
  if PathDialog.ShowModal <> mrOK then Exit;
  Self.importPaths.Clear;
  Self.importPaths.AddStrings( PathDialog.PathListbox.Items );
end;

procedure TProjConfigDlg.LinkerButtonClick(Sender: TObject);
begin
  LinkerListDlg.EditList( linkerFlags );
end;

end.