root/trunk/Source/source.d

/**************************************************************************

        @file source.d

        Copyright (c) 2005 Derek Parnell

        This software is provided 'as-is', without any express or implied
        warranty. In no event will the authors be held liable for damages
        of any kind arising from the use of this software.

        Permission is hereby granted to anyone to use this software for any
        purpose, including commercial applications, and to alter it and/or
        redistribute it freely, subject to the following restrictions:

        1. The origin of this software must not be misrepresented; you must
           not claim that you wrote the original software. If you use this
           software in a product, an acknowledgment within documentation of
           said product would be appreciated but is not required.

        2. Altered source versions must be plainly marked as such, and must
           not be misrepresented as being the original software.

        3. This notice may not be removed or altered from any distribution
           of the source.

        4. Derivative works are permitted, but they must carry this notice
           in full and credit the original source.


                        ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


        @version        Initial version, January 2005
        @author         Derek Parnell


**************************************************************************/

module source;
private import source_bn;    // Build number for this module
version(D_Version2)
{
    mixin("alias const(wchar)[] wstring;");
    mixin("alias const(dchar)[] dstring;");
    mixin("alias const(dchar)   dcharc;");
    mixin("alias const(wchar)   wcharc;");
    mixin("alias const(char)    charc;");
}
else
{
    alias char[] string;
    alias wchar[] wstring;
    alias dchar[] dstring;
    alias wchar   wcharc;
    alias dchar   dcharc;
    alias char    charc;
}


version(unix)  version = Unix;
version(Unix)  version = Posix;
version(linux)  version = Posix;
version(darwin) version = Posix;

private
{
//    alias char[] string;

    static import opts;

    static import util.str;
    static import util.fdt;
    static import util.pathex;
    static import util.fileex;
    static import util.macroex;
    static import util.booltype;   // definition of True and False
    alias util.booltype.True True;
    alias util.booltype.False False;
    alias util.booltype.Bool Bool;

    static import std.stdio;
    static import std.path;
    static import std.ctype;
    static import std.file;
    static import std.string;
}

public
{
    enum eRuleUsage
    {
        Ignore,
        Compile,
        Link
    }
    string function(string pPath) AddRoot;
    void function(string pArg) AddCompilerArg;
    string[] function () GetImportRoots;
    Bool function() AutoImports;
    void function(string pPath) AddTarget;
    void function(string pPath) AddLink;
    void function(string pText, bool pReplace=false) AddBuildDef;
    string[] function( ) ModulesToIgnore;
    string function(string pFile, string[] pScanList = null) GetFullPathname;
    string function(string pFile, int pScanList) GetFullPathnameScan;
    string function() GetAppPath;

    Bool    mMacroInput;
    Bool    mCollectUses;
    string  ObjWritePath;

}

private
{
    import util.str;
    import util.fdt;
    import util.pathex;
    import util.fileex;
    import util.macroex;
    import util.booltype;

    import std.stdio;
    import std.path;
    import std.ctype;
    import std.file;
    import std.string;

    const {

        // Using these as the literals confuses my text editor's
        // 'bracket matching' algorithm.
        static string kOpenBrace = "\x7B";
        static string kCloseBrace = "\x7D";
        static string kOpenParen = "\x28";
        static string kCloseParen = "\x29";

    }

    bool [string] AttributeBlocks;
    Bool mainFound;
    bool mainGUI;
    bool mainDLL;
    bool[string] vActiveVersions;
    long         vVersionLevel = 0;
    bool[string] vActiveDebugs;
    long         vDebugLevel = 0;
    string[eRuleUsage] vUseNames;


    class SourceException : Error
    {
        this(string pMsg)
        {
            super (Source.classinfo.name ~ ":" ~ pMsg);
        }
    }

}

    debug(1)
    {
        private import std.stdio;
    }

// Module Constructor -----------------
static this()
{
    AttributeBlocks["private"] = true;
    AttributeBlocks["package"] = true;
    AttributeBlocks["protected"] = true;
    AttributeBlocks["public"] = true;
    AttributeBlocks["export"] = true;
    mMacroInput = False;
    mainFound = False;
    vUseNames[eRuleUsage.Ignore] = "ignore";
    vUseNames[eRuleUsage.Compile] = "compile";
    vUseNames[eRuleUsage.Link] = "link";
    debug(1)
    {
    writefln("%s: " ~ __FILE__ ~ " build #%d", opts.MyName, source_bn.auto_build_number);
    }
}

// Module Destructor -----------------
static ~this()
{
    // Clean up any resources held by the source files.
    Source.Finalize();
}

// Class -----------------
public class Source {
    static {
        private
        {
            Source[string] smSourceIndex;
            string[] smScanOrder;
            bool[string] smUses;
            bool[string] smUsedBy;
        }
        public
        {
            enum EMode
            {
                New,            // Must be a new source file
                Update          // Must update an existing record
            }
            int FileCount() { return smSourceIndex.length; }

            Source opIndex(string pFileName)
            {
                Source* lObject;
                if ((lObject = (pFileName in smSourceIndex)) !is null)
                    return *lObject;
                if ((lObject = (ReducePathName(pFileName) in smSourceIndex)) !is null)
                    return *lObject;
                return null;
            }

            int AllFiles(int delegate(inout int lCnt, inout Source) dg)
            {
                int result = 0;
                int lCnt = 0;

                foreach (string lFileName; smScanOrder)
                {
                    result = dg(lCnt, smSourceIndex[lFileName]);
                    if (result != 0)
                        break;
                    lCnt++;
                }
                return result;
            }

            string[] AllFiles()
            {
                return smScanOrder;
            }

            string[] Uses() { return smUses.keys; }
            string[] UsedBy() { return smUsedBy.keys; }

        }
    } // static

    private
    {
        string mFileName;
        string mModuleName;
        string mObjectName;
        FileDateTime mObjectTime;     /* time of object file, must be newest, otherwise compile */
        FileDateTime mDependantsTime;   /* time of newest of all dependencies */
        FileDateTime mFileTime;
        bool mHasBeenSearched;
        bool mNoLink;
        bool mNoCompile;
        bool mIgnore;
        int mBuildNumber;
        string[] mReferencedImports;
        bool[string] mActiveVersions;
        long         mVersionLevel = 0;
        bool[string] mActiveDebugs;
        long         mDebugLevel = 0;
        string  mLocalArgs;
    } // private

    public
    {
    // FileName (read only)
    string FileName () { return mFileName; }

    // DependantsTime (read only)
    FileDateTime DependantsTime() { return mDependantsTime; }

    // ObjectsTime (read only)
    FileDateTime ObjectsTime() { return mObjectTime; }

    // FilesTime (read only)
    FileDateTime FilesTime() { return mFileTime; }

    // ModuleName (read only)
    string ModuleName() { return mModuleName; }

    // ObjectName (read only)
    string ObjectName() { return mObjectName; }

    // NoLink (read only)
    bool NoLink() { return mNoLink; }

    // NoCompile (read only)
    bool NoCompile() { return mNoCompile; }

    // Ignore
    bool Ignore() { return mIgnore; }
    bool Ignore(bool pNew) { mIgnore = pNew; return pNew;}

    // BuildNumber (read only)
    int BuildNumber() { return mBuildNumber; }

    // LocalArgs (read only)
    string LocalArgs () { return mLocalArgs; }

    // HasBeenScanned (read only)
    bool HasBeenScanned () { return mHasBeenSearched; }

// --------------------------------------------------------------------
    static void Finalize()
// --------------------------------------------------------------------
    {
        for(int i = smScanOrder.length-1; i >= 0; i--)
        {
            Source x;
            x = smSourceIndex[smScanOrder[i]];
            delete x;
        }
    }
// --------------------------------------------------------------------
    this(string pFileName, EMode pMode = Source.EMode.New)
// --------------------------------------------------------------------
    {
        if (pFileName in Source.smSourceIndex)
        {
            if (pMode == Source.EMode.Update)
            {
                Source.smSourceIndex[pFileName].create("");
            }
            else
            {
                mIgnore = true;
                mHasBeenSearched = true;
                mNoLink = true;
            }

        }
        else
        {
            create(pFileName);
        }
    }

// --------------------------------------------------------------------
    void create(string pFileName)
// --------------------------------------------------------------------
    {
        string lObjectName;

        mReferencedImports.length = 0;
        mHasBeenSearched = false;
        mIgnore = false;
        if (pFileName.length > 0)
        {
            mFileName = pFileName;
            // Store this instantiation in the list of known files.
            smSourceIndex[pFileName] = this;
        }
        else
        {
            pFileName = mFileName;
        }

        if (std.path.getExt(pFileName) != "ddoc")
        {
            string lAltName;
            mNoLink = (std.path.getExt(pFileName) == "di");
            mModuleName = FileToModulename(pFileName, lAltName);
            lObjectName = addExt(pFileName,opts.ObjExtension);
            mObjectName = ReducePathName(ExpandPathName(lObjectName, False));
        }
        else
        {
            mNoLink = true;
            mModuleName = "";
            lObjectName = "";
            mObjectName = "";
        }

        /* If a specific path for object files has been supplied
           on the command line, and the current source file is
           relative to the current directory, then we need to
           prepend the specified object location path.
        */
        if (ObjWritePath.length != 0 && mObjectName.length != 0)
        {
            if (mObjectName == lObjectName)
            {
                mObjectName = ObjWritePath ~ std.path.getBaseName(mObjectName);
                util.pathex.MakePath(mObjectName);
            }
        }

        if (opts.UseModBaseName == True)
        {
            mObjectName = getBaseName(mObjectName);
        }

        mBuildNumber = -1;

        mFileTime = new util.fdt.FileDateTime(pFileName);
        mDependantsTime  = mFileTime;

        mObjectTime   = new util.fdt.FileDateTime(mObjectName);
        UpdateDependantTime(mObjectTime);
        version(BuildVerbose)
        {
            if(opts.Verbose == True)
            {
                if (mFileTime !is null)
                    writefln("%s: Time %s for source %s", opts.MyName, mFileTime.toString(), mFileName);

                if (mObjectTime !is null)
                    writefln("%s: Time %s for object %s", opts.MyName, mObjectTime.toString(), mObjectName);
            }
        }

        search();
    }

debug(dtor)
    {
// --------------------------------------------------------------------
    ~this()
// --------------------------------------------------------------------
    {
        writefln("%s: Finis: %s", opts.MyName, mFileName);
    }
}


// --------------------------------------------------------------------
    void search()
// --------------------------------------------------------------------
    {
        FileDateTime lCurFileTime;
        bool lCanUse;
        int lTextPos = 0;
        string lFileText;


        if(mHasBeenSearched)
        {
            return;
        }

        if (util.file2.FileExists(mFileName) == false)
        {
            throw new SourceException("File '" ~ mFileName ~ "' does not exist.");
            //return;
        }

        version(BuildVerbose)
        {
            if(opts.Verbose == True)
                writefln("%s: Scanning %s", opts.MyName, ReducePathName(mFileName));
        }

        if (mHasBeenSearched == false)
        {
            smScanOrder.length = smScanOrder.length + 1;
            smScanOrder[$-1] = mFileName;
        }

        if (std.path.getExt(mFileName) != "ddoc")
        {
            // Grab the original text, which must exist.
            lFileText = GetText(mFileName, GetOpt.Exists);

            // Check if any macro processing is required.
            if ((mMacroInput == True) && (std.path.getExt(mFileName) != "d"))
            {
                string lNewFile;
                bool lChanged;
                lNewFile = util.pathex.ReplaceExtension(mFileName, "d");
                if (util.macroex.RunMacro(lFileText, "build", lNewFile, lChanged))
                {
                    std.file.write(lNewFile, lFileText);
                    mHasBeenSearched = true;
                    mIgnore = true;
                    version(BuildVerbose)
                    {
                        if(opts.Verbose == True)
                            writefln("%s: Macro output %s", opts.MyName, lNewFile);
                    }
                    new Source(lNewFile);
                    delete lFileText;
                    return;
                }
            }

            // Extract all the module references.
            ProcessTokens(lFileText, lTextPos);
            delete lFileText; // Remove it from GC control.

            lCurFileTime = new FileDateTime();
            // Examine each extracted module file.
            if ( (mReferencedImports.length > 0) && (AutoImports() == True))
            {

                AddRoot( std.path.getDirName(ExpandPathName(mFileName, False)) );
            }

            foreach(string lNextFile; mReferencedImports)
            {
                if (mCollectUses)
                {
                    smUses[mFileName ~ " <> " ~ lNextFile] = true;
                    smUsedBy[lNextFile ~ " <> " ~ mFileName] = true;
                }
                if(lNextFile in smSourceIndex)
                {
                    // Known file so just grab its mod time
                    lCurFileTime = smSourceIndex[lNextFile].DependantsTime;
                }
                else
                {
                    // Ignore specified modules as we assume they are in the lib.
                    lCanUse = true;
                    if (!(ModulesToIgnore is null))
                    {
                        foreach(string lNextModule; ModulesToIgnore() ){
                            int lFindPos;
                            string lType = "package";
                            string lFullFileName;
                            version(Windows)
                            {
                                string lLowerMod;
                                lFullFileName = std.string.tolower(ExpandPathName(lNextFile, True));
                                lLowerMod = std.string.tolower(lNextModule);
                                version(Windows)
                                {
                                    // Just in case a Windows user used unix style separators.
                                    lLowerMod = std.string.replace(lLowerMod, `/`, `\`);
                                }

                                // Check for package name
                                lFindPos = std.string.find(lFullFileName,
                                                        std.path.sep ~ lLowerMod ~ std.path.sep);
                                if (lFindPos == -1) {
                                    // It might be a package at the current module level.
                                    lFindPos = std.string.find(lFullFileName,
                                                        lLowerMod ~ std.path.sep);
                                    if (lFindPos != 0)
                                        lFindPos = -1;
                                }
                                // Check for module in subdirectory
                                if (lFindPos == -1) {
                                    lType = "module";
                                    lFindPos = std.string.find(lFullFileName,
                                                        std.path.sep ~ lLowerMod ~ ".d");
                                }
                                // Check for module in current directory
                                if (lFindPos == -1)
                                {
                                    lType = "module";
                                    if (lFullFileName == source.ExpandPathName(lLowerMod ~ ".d", True))
                                        lFindPos = 0;
                                }
                            }
                            version(Posix)
                            {
                                // Check for package name
                                lFullFileName = source.ExpandPathName(lNextFile, True);
                                lFindPos = std.string.find(lFullFileName,
                                                        std.path.sep ~ lNextModule ~ std.path.sep);
                                if (lFindPos == -1) {
                                    // It might be a package at the current module level.
                                    lFindPos = std.string.find(lFullFileName,
                                                        lNextModule ~ std.path.sep);
                                    if (lFindPos != 0)
                                        lFindPos = -1;
                                }
                                // Check for module in subdirectory
                                if (lFindPos == -1) {
                                    lType = "module";
                                    lFindPos = std.string.find(lFullFileName,
                                                        std.path.sep ~ lNextModule ~ ".d");
                                }
                                // Check for module in current directory
                                if (lFindPos == -1) {
                                    lType = "module";
                                    if (lFullFileName == ExpandPathName(lNextModule ~ ".d", False))
                                        lFindPos = 0;
                                }
                            }

                            if( lFindPos >= 0) {
                                version(BuildVerbose)
                                {
                                    if (opts.Verbose == True)
                                        writefln("%s: Ignoring %s (%s: %s)", opts.MyName, lNextFile, lType, lNextModule);
                                }

                                lCanUse = false;
                                break;
                            }
                        }
                    }
                    if (lCanUse && (opts.Explicit == False))
                    {
                        // Not known yet, so add it and grab its mod time
                        string lUseName = GetFullPathnameScan(lNextFile, ~0);
                        lCurFileTime = (new Source(lUseName)).DependantsTime;
                    }

                }
            }

            // Ensure we get the most recent mod time.
            UpdateDependantTime (lCurFileTime);

        }
        mHasBeenSearched = true;